Add flake support

.gitignore

@@ -1 +1,2 @@
 *.pyc
+/result

boot.nix

@@ -0,0 +1,45 @@
+{ pkgs, vmrunner }:
+
+let
+  mk = chainloader: { name ? "unikernel", extraFlags ? [], kvm ? false, cfg }:
+    pkgs.symlinkJoin {
+      name = "boot-${name}";
+      paths = [ vmrunner ];
+      buildInputs = [ pkgs.makeWrapper ];
+
+      postBuild = ''
+        wrapProgram $out/bin/boot \
+          --set INCLUDEOS_CHAINLOADER ${chainloader}/bin/ \
+          --add-flags "${builtins.concatStringsSep " " cfg.vm.args}" \
+          ${pkgs.lib.optionalString kvm "--add-flags --kvm"} \
+          ${pkgs.lib.optionalString (extraFlags != []) (
+            "--add-flags \"" + builtins.concatStringsSep " " extraFlags + "\""
+          )}
+      '';
+    };
+
+  mkBoot = chainloader: cfg:
+    rec {
+      run = mk chainloader {
+        name = "${cfg.name or "unikernel"}-run";
+        inherit cfg;
+      };
+
+      debug = mk chainloader {
+        name = "${cfg.name or "unikernel"}-debug";
+        extraFlags = [ "-d" ];
+        inherit cfg;
+      };
+
+      kvm = mk chainloader {
+        name = "${cfg.name or "unikernel"}-kvm";
+        kvm = true;
+        inherit cfg;
+      };
+
+      default = run;
+    };
+in
+{
+  mkBoot = mkBoot;
+}

default.nix

@@ -17,6 +17,11 @@ pkgs.python3.pkgs.buildPythonPackage rec {
     psutil
   ];
 
+  propagatedBuildInputs = [
+    pkgs.file
+    pkgs.qemu
+  ];
+
   create_bridge = ./vmrunner/bin/create_bridge.sh;
 
   passthru = {

flake.nix

@@ -0,0 +1,38 @@
+{
+  description = "A convenience wrapper around qemu for IncludeOS integration tests";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/25.05";
+  };
+
+  outputs = { self, nixpkgs }:
+    let
+      system = "x86_64-linux";
+      pkgs = import nixpkgs { inherit system; };
+
+      vmrunner = pkgs.callPackage ./default.nix {};
+
+      vmconfig = import ./vmconfig.nix { inherit pkgs; };
+      boot = import ./boot.nix { inherit pkgs vmrunner; };
+
+      mkBoot = chainloader:
+      { mem ? "128m" }:
+        let
+          cfg = vmconfig.mkConfig { inherit mem; };
+        in
+          boot.mkBoot chainloader { vm = cfg; };
+
+    in {
+      packages.${system}.default = vmrunner;
+
+      devShells.${system}.default = import ./shell.nix { inherit pkgs; };
+
+      lib.${system}.mkBoot = mkBoot;
+
+      apps.${system}.default = {
+        type = "app";
+        program = "${vmrunner}/bin/boot";
+      };
+
+    };
+}

vmconfig.nix

@@ -0,0 +1,23 @@
+{ pkgs }:
+
+let
+  memToMiB = mem:
+    let
+      g = builtins.match "^([0-9]+)[Gg]$" mem;
+      m = builtins.match "^([0-9]+)[Mm]$" mem;
+    in
+      if g != null then (builtins.fromJSON (builtins.head g)) * 1024
+      else if m != null then builtins.fromJSON (builtins.head m)
+      else throw "invalid mem: ${mem}";
+in
+{
+  mkConfig = { mem ? "128m" }:
+    let
+      memMiB = memToMiB mem;
+      vmJson = pkgs.writeText "vm.json"
+        (builtins.toJSON { inherit memMiB; });
+    in {
+      inherit memMiB vmJson;
+      args = [ "-j" vmJson ];
+    };
+}